Skonsoliduj kilka wyzwalaczy Oracle. Jakiś wpływ na wydajność?

Przeprowadziłem teraz analizę porównawczą tej sytuacji i doszedłem do wniosku, że po dodaniu 1 wyzwalacza następuje znaczna utrata wydajności najprawdopodobniej z powodu przełączania kontekstu PL/SQL. W moim benchmarku strata wynosi 8 razy. Jednak dodanie drugiego „zgodnego” wyzwalacza nie ma już większego wpływu. Przez „zgodny” rozumiem, że oba wyzwalacze zawsze uruchamiają się w tym samym zdarzeniu w dowolnej kolejności.

Dochodzę więc do wniosku, że najprawdopodobniej jest tylko 1 SQL -> PL/SQL przełącznik kontekstowy dla wszystkich wyzwalaczy

Oto test porównawczy:

Utwórz tabelę

-- A typical table with primary key, creation/modification user/date, and 
-- other data columns
CREATE TABLE test(
  id number(38)    not null, -- pk
  uc varchar2(400) not null, -- creation user
  dc date          not null, -- creation date
  um varchar2(400),          -- modification user
  dm date,                   -- modification date
  data number(38)
);

... i sekwencja

CREATE SEQUENCE s_test;

Typowy identyfikator ustawienia wyzwalacza, utworzenie/zmiana użytkownika/data

CREATE OR REPLACE TRIGGER t_test BEFORE INSERT OR UPDATE
  ON test
  FOR EACH ROW
BEGIN
  IF inserting THEN
    SELECT s_test.nextval INTO :new.id FROM dual;

    :new.uc := USER;
    :new.dc := SYSDATE;
    :new.um := NULL;
    :new.dm := NULL;
  END IF;
  IF updating THEN
    :new.um := USER;
    :new.dm := SYSDATE;
    :new.uc := :old.uc;
    :new.dc := :old.dc;
  END IF;
END t_test;

Wstaw 1000, 10000, 100000 rekordów

declare
  procedure run (limit number) is
    t timestamp;
  begin
    t := systimestamp;

    insert into test (data)
    select level from dual connect by level < limit;

    dbms_output.put_line(to_char(systimestamp - t));

    rollback;
  end;
begin
  run(1000);
  run(10000);
  run(100000);
end;

Wyniki

-- ------------------------------------
-- +000000000 00:00:00.086603000
-- +000000000 00:00:00.844333000
-- +000000000 00:00:08.429186000
-- ------------------------------------

Kolejny „zgodny” wyzwalacz (kolejność wykonania nieistotna)

CREATE OR REPLACE TRIGGER t_test_other BEFORE INSERT OR UPDATE
  ON test
  FOR EACH ROW
BEGIN
  :new.data := 42;
END t_test_other;

Wyniki kolejnego uruchomienia skryptu testowego

-- ------------------------------------
-- +000000000 00:00:00.088551000
-- +000000000 00:00:00.876028000
-- +000000000 00:00:08.731345000
-- ------------------------------------

Wyłącz wyzwalacze

alter trigger t_test disable;
alter trigger t_test_other disable;

Uruchom nieco inny skrypt testowy

declare
  procedure run (limit number) is
    t timestamp;
  begin
    t := systimestamp;

    insert into test (id, uc, dc, data)
    select s_test.nextval, user, sysdate, level from dual 
    connect by level < limit;

    dbms_output.put_line(to_char(systimestamp - t));

    rollback;
  end;
begin
  run(1000);
  run(10000);
  run(100000);
end;

Wyniki

-- ------------------------------------
-- +000000000 00:00:00.012712000
-- +000000000 00:00:00.104903000
-- +000000000 00:00:01.043984000
-- ------------------------------------