Znajdź i zamień ciąg w pliku BLOB for Work lub Excel

Pliki Microsoft Word i Excel nie są plikami tekstowymi, w których można po prostu zastąpić tekst i które na pewno nie będą działać z BLOB . docx i xlsx pliki są w rzeczywistości plikami zip (spróbuj zmienić rozszerzenie pliku i rozpakować, aby zobaczyć na własne oczy), które zawierają definicję XML dokumentu. Musisz więc:

1. Rozpakuj plik
2. Konwertuj plik, który wymaga zmiany z BLOB do CLOB
3. Zmodyfikuj zawartość odpowiedniego pliku XML
4. Konwertuj plik z powrotem na BLOB z CLOB
5. Dodaj zmodyfikowany plik z powrotem do pliku zip

Napisałem poniższy kod jako przykład, jak dokonać zamiany na docx plik. Dla xlsx pliki, każdy arkusz Excel jest zawarty w innym pliku XML, więc będziesz musiał nieznacznie zmodyfikować kod, aby działał z obydwoma typami plików.

Kod używa APEX_ZIP pakiet, który znacznie upraszcza pracę z plikami zip, a także sprawia, że ​​przykładowy kod jest nieco bardziej przejrzysty, co się dzieje. Jeśli nie masz zainstalowanego APEX, musisz dowiedzieć się, jak rozpakować/ponownie rozpakować pliki przy użyciu posiadanych pakietów Oracle.

DECLARE
    l_old_file       BLOB;
    l_new_file       BLOB;
    l_files          apex_zip.t_files;
    l_document       BLOB;
    l_clob           CLOB;
    l_dest_offsset   INTEGER;
    l_src_offsset    INTEGER;
    l_lang_context   INTEGER := DBMS_LOB.default_lang_ctx;
    l_warning        INTEGER;
BEGIN
    -- Get the blob you want to "correct"
    SELECT blob_content
      INTO l_old_file
      FROM apex_application_temp_files
     WHERE ROWNUM = 1;

    -- Get a list of all the file names contained within the zip
    l_files := apex_zip.get_files (l_old_file);

    -- Loop through all the files adding each one to the new zip
    FOR i IN l_files.FIRST .. l_files.LAST
    LOOP
        l_document := apex_zip.get_file_content (l_old_file, l_files (i));

        IF l_files (i) = 'word/document.xml'
        THEN
            -- if the file name is word/document.xml then make the changes to it
            
            DBMS_LOB.createTemporary (lob_loc => l_clob, cache => FALSE);

            l_dest_offsset := 1;
            l_src_offsset := 1;

            DBMS_LOB.converttoclob (dest_lob       => l_clob,
                                    src_blob       => l_document,
                                    amount         => DBMS_LOB.lobmaxsize,
                                    dest_offset    => l_dest_offsset,
                                    src_offset     => l_src_offsset,
                                    blob_csid      => DBMS_LOB.default_csid,
                                    lang_context   => l_lang_context,
                                    warning        => l_warning);

            --------------------
            -- This is where you would do any replacements
            --------------------
            l_clob := REPLACE (l_clob, 'www.google.co.uk', 'www.google.com');
            --------------------

            l_dest_offsset := 1;
            l_src_offsset := 1;

            DBMS_LOB.CONVERTTOBLOB (dest_lob       => l_document,
                                    src_clob       => l_clob,
                                    amount         => DBMS_LOB.lobmaxsize,
                                    dest_offset    => l_dest_offsset,
                                    src_offset     => l_src_offsset,
                                    blob_csid      => DBMS_LOB.default_csid,
                                    lang_context   => l_lang_context,
                                    warning        => l_warning);
        END IF;

        apex_zip.add_file (l_new_file, l_files (i), l_document);
    END LOOP;

    apex_zip.finish (l_new_file);
    --Do whatever you want with the "new" file here
END;