Optymalizacja jednoczesnych żądań ImageMagick za pomocą redis/php-resque

Twoje polecenie sprowadza się do tego:

convert -size 600x400 xc:none                                 \
    \( 1.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 2.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 3.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 4.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 5.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 6.png -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    result.png

Moje myśli są następujące:

Punkt 1:

Pierwszy -composite na puste płótno wydaje się bezcelowe - przypuszczalnie 1.png to PNG o wymiarach 600 x 400 z przezroczystością, dzięki czemu pierwsza linia może uniknąć operacji składania i zaoszczędzić 16% czasu przetwarzania, zmieniając na:

convert -background none 1.png -fill ... -colorize 100% \
   \( 2.png ..
   \( 3.png ...

Punkt 2

Umieściłem odpowiednik twojego polecenia w pętli i wykonałem 100 iteracji, co zajmuje 15 sekund. Następnie zmieniłem wszystkie odczyty plików PNG na odczyty MPC pliki - lub pliki Magick Pixel Cache. To skróciło czas przetwarzania do niecałych 10 sekund, czyli o 33%. Magic Pixel Cache to po prostu wstępnie zdekompresowany, wstępnie zdekodowany plik, który można odczytać bezpośrednio w pamięci bez użycia procesora. Możesz je wstępnie utworzyć po każdej zmianie katalogu i przechowywać je razem z plikami PNG. Aby to zrobić, to zrobisz

convert image.png image.mpc

a otrzymasz image.mpc i image.cache . Następnie po prostu zmień kod, aby wyglądał tak:

convert -size 600x400 xc:none                                 \
    \( 1.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 2.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 3.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 4.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 5.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    \( 6.mpc -fill rgb\(x,y,z\) -colorize 100% \) -composite  \
    result.png

Punkt 3

Niestety nie odpowiedziałeś jeszcze na moje pytania, ale jeśli Twój katalog zasobów nie jest zbyt duży, możesz umieścić go (lub powyższe odpowiedniki MPC) na dysku RAM podczas uruchamiania systemu.

Punkt 4

Zdecydowanie powinieneś biegać równolegle – to przyniesie największe korzyści. Jest to bardzo proste z GNU Parallel – przykład tutaj.

Jeśli używasz REDIS, jest to łatwiejsze. Wystarczy LPUSH Twoje obrazy zakodowane w MIME na listę REDIS w następujący sposób:

#!/usr/bin/perl
################################################################################
# generator.pl <number of images> <image size in bytes>
# Mark Setchell
# Base64 encodes and sends "images" of specified size to REDIS
################################################################################
use strict;
use warnings FATAL => 'all';
use Redis;
use MIME::Base64;
use Time::HiRes qw(time);

my $Debug=0;    # set to 1 for debug messages

my $nargs = $#ARGV + 1;
if ($nargs != 2) {
    print "Usage: generator.pl <number of images> <image size in bytes>\n";
    exit 1;
}

my $nimages=$ARGV[0];
my $imsize=$ARGV[1];

# Our "image"
my $image="x"x$imsize;

printf "DEBUG($$): images: $nimages, size: $imsize\n" if $Debug;

# Connection to REDIS
my $redis = Redis->new;
my $start=time;

for(my $i=0;$i<$nimages;$i++){
   my $encoded=encode_base64($image,'');
   $redis->rpush('images'=>$encoded);
   print "DEBUG($$): Sending image $i\n" if $Debug;
}
my $elapsed=time-$start;
printf "DEBUG($$): Sent $nimages images of $imsize bytes in %.3f seconds, %d images/s\n",$elapsed,int($nimages/$elapsed);

a następnie uruchom wielu pracowników, z których wszyscy siedzą i wykonują BLPOP zadań do wykonania

#!/usr/bin/perl
################################################################################
# worker.pl
# Mark Setchell
# Reads "images" from REDIS and uudecodes them as fast as possible
################################################################################
use strict;
use warnings FATAL => 'all';
use Redis;
use MIME::Base64;
use Time::HiRes qw(time);

my $Debug=0;    # set to 1 for debug messages
my $timeout=1;  # number of seconds to wait for an image
my $i=0;

# Connection to REDIS
my $redis = Redis->new;

my $start=time;

while(1){
   #my $encoded=encode_base64($image,'');
   my (undef,$encoded)=$redis->blpop('images',$timeout);
   last if !defined $encoded;
   my $image=decode_base64($encoded);
   my $l=length($image);
   $i++; 
   print "DEBUG($$): Received image:$i, $l bytes\n" if $Debug;
}

my $elapsed=time-$start-$timeout; # since we waited that long for the last one
printf "DEBUG($$): Received $i images in %.3f seconds, %d images/s\n",$elapsed,int($i/$elapsed);

Jeśli uruchomię jeden proces generatora jak powyżej i zlecę wygenerowanie 100 000 obrazów o wielkości 200 kB każdy i odczytam je za pomocą 4 procesów roboczych na moim iMacu o rozsądnej specyfikacji, zajmie to 59 sekund, czyli około 1700 obrazów/s może przejść przez REDIS.