czy mogę prowadzić jedną sesję Oracle od dwóch klientów oci?

Jeśli używasz bazy danych 11g, możesz użyć DBMS_XA pakietaby umożliwić jednej sesji dołączenie do transakcji rozpoczętej przez pierwszą sesję. Jak demonstruje Tim Hall, możesz rozpocząć transakcję w jednej sesji, dołączyć do tej transakcji z innej sesji i przeczytać niezatwierdzone zmiany wprowadzone w transakcji. Niestety jednak nie pomoże to w przypadku zmiennych sesji (zakładając, że „zmienna sesji” oznacza zmienną pakietu, która ma zasięg sesji).

 
 Utwórz pakiet i tabelę:
 CREATE TABLE foo( col1 NUMBER );

create or replace package pkg_foo
as
  g_var number;
  procedure set_var( p_in number );
end;

create or replace package body pkg_foo
as
  procedure set_var( p_in number )
  as
  begin
    g_var := p_in;
  end;
end;
 
 W sesji 1 rozpoczynamy transakcję globalną, ustawiamy zmienną pakietu i wstawiamy wiersz do tabeli przed zawieszeniem transakcji globalnej (co pozwala na jej wznowienie przez inną sesję)
 SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4  begin
  5    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmnoflags );
  6    pkg_foo.set_var(42);
  7    dbms_output.put_line( 'Set pkg_foo.g_var to ' || pkg_foo.g_var );
  8    insert into foo values( 42 );
  9    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuspend );
 10* end;
SQL> /
Set pkg_foo.g_var to 42

PL/SQL procedure successfully completed.
 
 W sesji 2 wznawiamy transakcję globalną, odczytujemy z tabeli, odczytujemy zmienną sesji i kończymy transakcję globalną. Zwróć uwagę, że zapytanie względem tabeli widzi wiersz, który wstawiliśmy, ale zmiana zmiennej pakietu nie jest widoczna.
 SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4    l_col1 integer;
  5  begin
  6    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmresume );
  7    dbms_output.put_line( 'Read pkg_foo.g_var as ' || pkg_foo.g_var );
  8    select col1 into l_col1 from foo;
  9    dbms_output.put_line( 'Read COL1 from FOO as ' || l_col1 );
 10    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuccess );
 11* end;
SQL> /
Read pkg_foo.g_var as
Read COL1 from FOO as 42

PL/SQL procedure successfully completed.
 
 Aby udostępnić stan sesji między sesjami, można by użyć globalny kontekst aplikacji
 zamiast używać zmiennych pakietu? Możesz to połączyć z DBMS_XA pakiety, jeśli chcesz czytać zarówno tabele bazy danych, jak i stan sesji.
 
 Utwórz kontekst i pakiet za pomocą funkcji pobierającej i ustawiającej
 CREATE CONTEXT my_context
  USING pkg_foo
  ACCESSED GLOBALLY;

create or replace package pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number );
  function get_var( p_session_id in number )
    return number;
end;

create or replace package body pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number )
  as
  begin
    dbms_session.set_identifier( p_session_id );
    dbms_session.set_context( 'MY_CONTEXT', 'G_VAR', p_in, null, p_session_id );
  end;
  function get_var( p_session_id in number )
    return number
  is
  begin
    dbms_session.set_identifier( p_session_id );
    return sys_context('MY_CONTEXT', 'G_VAR');
  end;
end;
 
 W sesji 1 ustaw wartość zmiennej kontekstowej G_VAR do 47 dla sesji 12345
 begin
  pkg_foo.set_var( 12345, 47 );
end;
 
 Teraz sesja 2 może odczytać wartość z kontekstu
   1* select pkg_foo.get_var( 12345 ) from dual
SQL> /

PKG_FOO.GET_VAR(12345)
----------------------
                    47