Próbujesz użyć typów na poziomie pakietu w zwykłym języku SQL, co jest niedozwolone. Typy zadeklarowane w pakiecie nie są widoczne ani ważne poza PL/SQL (lub nawet w zwykłych instrukcjach SQL w PL/SQL). Okrojona wersja tego, co robisz:
create or replace package types as
type my_rec_type is record (dummy dual.dummy%type);
type my_table_type is table of my_rec_type index by binary_integer;
end types;
/
create or replace package p42 as
function get_table return types.my_table_type;
end p42;
/
create or replace package body p42 as
function get_table return types.my_table_type is
my_table types.my_table_type;
begin
select * bulk collect into my_table from dual;
return my_table;
end get_table;
end p42;
/
select * from table(p42.get_table);
SQL Error: ORA-00902: invalid datatype
Nawet w pakiecie, jeśli masz procedurę, która próbowała użyć funkcji tabeli, wystąpiłby błąd. Jeśli dodałeś:
procedure test_proc is
begin
for r in (select * from table(get_table)) loop
null;
end loop;
end test_proc;
... kompilacja treści pakietu nie powiedzie się z ORA-22905: cannot access rows from a non-nested table item .
Musisz zadeklarować typy na poziomie schematu, a nie w pakiecie, więc używając SQL create type polecenie
:
create type my_obj_type is object (dummy varchar2(1));
/
create type my_table_type is table of my_obj_type;
/
create or replace package p42 as
function get_table return my_table_type;
end p42;
/
create or replace package body p42 as
function get_table return my_table_type is
my_table my_table_type;
begin
select my_obj_type(dummy) bulk collect into my_table from dual;
return my_table;
end get_table;
end p42;
/
select * from table(p42.get_table);
DUMMY
-----
X
