W odpowiedzi na Twoje poprzednie pytanie wspomniałem, że wypełnienie kolekcji byłoby trudniejsze z %rowtype pole. O ile mi wiadomo, o ile nie zadeklarujesz typu obiektu na poziomie SQL zamiast typu rekordu, nie możesz użyć bulk collect w tym celu (choć warto sprawdzić, czy to się zmieniło w 12c).
Uważam, że utknąłeś w używaniu prostszej pętli kursora, która buduje dwa pola w twoim typie (tj. %rowtype podpole i rowid pole) oddzielnie, a następnie buduje kolekcję pojedynczo:
create or replace package body dat_pkg is
procedure transform_dat (p_batch_name data_test.batch_name%type)
is
cursor cur_dat is
select rowid, a.*
from data_test a
where batch_name = p_batch_name;
l_dat_tst typ_dat_tst;
l_rec data_test%rowtype;
begin
for rec_dat in cur_dat loop
l_rec.data_id := rec_dat.data_id;
l_rec.data_value := rec_dat.data_value;
l_rec.batch_name := rec_dat.batch_name;
-- or use a counter you increment for this...
l_dat_tst(l_dat_tst.count + 1).data_rec := l_rec;
l_dat_tst(l_dat_tst.count).data_rowid := rec_dat.rowid;
end loop;
-- Do the Transformation here. Example --
for i in 1..l_dat_tst.count loop
if l_dat_tst(i).data_rec.data_value = 'hello' then
l_dat_tst(i).data_rec.data_value := 'was hello';
else
l_dat_tst(i).data_rec.data_value := 'was not hello';
end if;
end loop;
-- update the table
proc_test (p_dat => l_dat_tst);
end transform_dat;
procedure proc_test (p_dat typ_dat_tst)
is
begin
for i in 1..p_dat.count loop
update data_test
set data_value = p_dat(i).data_rec.data_value
where data_id = p_dat(i).data_rec.data_id
and rowid = p_dat(i).data_rowid;
end loop;
end proc_test;
end dat_pkg;
/
Jak również omówiono wcześniej, odwołania do pól rekordu pod-pola muszą być odpowiednio zakwalifikowane, więc wstawiłem .data_rec w piśmiennictwie w obu procedurach. Zmieniłem fikcyjną transformację, aby zmodyfikować wartość zamiast identyfikatora, ponieważ oznacza to, że nigdy nie nastąpią żadne aktualizacje.
Demo z fikcyjnymi danymi:
insert into data_test values (1, 'hello', 'test');
insert into data_test values (2, 'hello', 'test');
insert into data_test values (3, 'hello', 'exclude');
insert into data_test values (4, 'goodbye', 'test');
exec dat_pkg.transform_dat('test');
select * from data_test;
DATA_ID DATA_VALUE BATCH_NAME
---------- -------------------- --------------------
1 was hello test
2 was hello test
3 hello exclude
4 was not hello test
