SQL Server - Transakcje zagnieżdżone w procedurze składowanej

Możliwe jest, że praca wykonana przez dodatek SP2 zostanie wycofana i nie straci pracy wykonanej przez dodatek SP1. Ale aby tak się stało, musisz napisać swoje procedury składowane przy użyciu bardzo konkretnego wzorca, jak opisano w Obsługa wyjątków i transakcje zagnieżdżone :

create procedure [usp_my_procedure_name]
as
begin
    set nocount on;
    declare @trancount int;
    set @trancount = @@trancount;
    begin try
        if @trancount = 0
            begin transaction
        else
            save transaction usp_my_procedure_name;

        -- Do the actual work here

lbexit:
        if @trancount = 0   
            commit;
    end try
    begin catch
        declare @error int, @message varchar(4000), @xstate int;
        select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
        if @xstate = -1
            rollback;
        if @xstate = 1 and @trancount = 0
            rollback
        if @xstate = 1 and @trancount > 0
            rollback transaction usp_my_procedure_name;

        raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
    end catch   
end

Nie wszystkie błędy można naprawić, istnieje szereg warunków błędów, z których transakcja nie może się naprawić, najbardziej oczywistym przykładem jest zakleszczenie (jesteś powiadamiany o wyjątku zakleszczenia po transakcja została już wycofana). Zarówno SP1 jak i [email protected] muszą być napisane przy użyciu tego wzoru. Jeśli masz nieuczciwy SP lub chcesz w prosty sposób wykorzystać istniejące procedury składowane, które nie chcą wydawać ROLLBACK oświadczeń, wtedy Twoja sprawa jest przegrana.