Zindeksowane pole MySQL nie zapisuje wartości podczas tworzenia/edycji rekordu przez ADO

Udało mi się odtworzyć Twój problem z 64-bitową wersją sterownika Unicode MySQL ODBC 5.3 (5.03.04.00). Wygląda na to, że występuje problem z aktualizacjami zestawu rekordów ADO, gdy ostatnia kolumna w tabeli jest typu TEXT . Nie miałem nawet indeksu userid i uzyskałem te same wyniki.

Jednym z możliwych obejść byłoby użycie ADODB.Command z parametrami do wykonania wstawiania przy użyciu kodu podobnego do tego:

Dim oConn As ADODB.Connection
Dim cmd As ADODB.Command

Set oConn = New ADODB.Connection
oConn.Open _
        "Driver=MySQL ODBC 5.3 Unicode Driver;" & _
        "SERVER=localhost;" & _
        "UID=root;" & _
        "PWD=whatever;" & _
        "DATABASE=mydb;" & _
        "PORT=3306;" & _
        "DFLT_BIGINT_BIND_STR=1"

Set cmd = New ADODB.Command
cmd.ActiveConnection = oConn
cmd.CommandText = _
        "INSERT INTO phplist_user_user_history " & _
        "(`userid`, `ip`, `date`, `Summary`, `Detail`, `systeminfo`) " & _
        "VALUES (?,?,?,?,?,?)"
cmd.Parameters.Append cmd.CreateParameter("?", adInteger, adParamInput, , 456)
cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, "")
cmd.Parameters.Append cmd.CreateParameter("?", adDBTimeStamp, adParamInput, 255, Now)
cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, "cHistory.Subject")
cmd.Parameters.Append cmd.CreateParameter("?", adLongVarWChar, adParamInput, 2147483647, "cHistory.Body")
cmd.Parameters.Append cmd.CreateParameter("?", adLongVarWChar, adParamInput, 2147483647, "Automated syncronization process.")
cmd.Execute

Set cmd = Nothing
oConn.Close
Set oConn = Nothing

Przetestowałem go z bazy danych Access 2010 i dla mnie działało dobrze.