Przykład MySQL dla Visual Basic 6.0 — odczyt/zapis

Pobierz ODBC connector ze strony pobierania MySQL .

Poszukaj właściwego connectionstring ponad tutaj .

W projekcie VB6 wybierz odwołanie do Microsoft ActiveX Data Objects 2.8 Library . Możliwe, że masz też bibliotekę 6.0, jeśli masz Windows Vista lub Windows 7. Jeśli chcesz, aby twój program działał również na klientach Windows XP, lepiej z biblioteką 2.8. Jeśli masz Windows 7 z SP 1, Twój program nigdy nie będzie działał na żadnym innym systemie o niższych specyfikacjach z powodu błędu kompatybilności w SP1. Więcej informacji o tym błędzie znajdziesz w KB2517589 .

Ten kod powinien dostarczyć wystarczających informacji, aby rozpocząć pracę ze złączem ODBC.

Private Sub RunQuery()
    Dim DBCon As adodb.connection
    Dim Cmd As adodb.Command
    Dim Rs As adodb.recordset
    Dim strName As String

    'Create a connection to the database
    Set DBCon = New adodb.connection
    DBCon.CursorLocation = adUseClient
    'This is a connectionstring to a local MySQL server
    DBCon.Open "Driver={MySQL ODBC 5.1 Driver};Server=localhost;Database=myDataBase; User=myUsername;Password=myPassword;Option=3;"

    'Create a new command that will execute the query
    Set Cmd = New adodb.Command
    Cmd.ActiveConnection = DBCon
    Cmd.CommandType = adCmdText
    'This is your actual MySQL query
    Cmd.CommandText = "SELECT Name from Customer WHERE ID = 1"

    'Executes the query-command and puts the result into Rs (recordset)
    Set Rs = Cmd.Execute

    'Loop through the results of your recordset until there are no more records
    Do While Not Rs.eof
        'Put the value of field 'Name' into string variable 'Name'
        strName = Rs("Name")

        'Move to the next record in your resultset
        Rs.MoveNext
    Loop

    'Close your database connection
    DBCon.Close

    'Delete all references
    Set Rs = Nothing
    Set Cmd = Nothing
    Set DBCon = Nothing
End Sub