Dzielenie wartości rozdzielanych w kolumnie SQL na wiele wierszy

Jeśli korzystasz z SQL Server 2016+

Możesz użyć nowego STRING_SPLIT funkcji, o której pisałem tutaj na blogu, a Brent Ozar pisał tutaj.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Jeśli nadal korzystasz z wersji wcześniejszej niż SQL Server 2016

Utwórz funkcję podziału. To tylko jeden z wielu przykładów:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Omówiłem tutaj kilka innych i lepsze podejście niż dzielenie się tutaj.

Teraz możesz po prostu ekstrapolować:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Proponuję również nie umieszczać myślników w nazwach kolumn. Oznacza to, że zawsze musisz umieścić je w [square brackets] .