Grupuj wszystkie powiązane rekordy w relacji „wiele do wielu”, komponenty połączone wykresem SQL

Myślałem o użyciu rekurencyjnego CTE , ale o ile wiem, w SQL Server nie jest możliwe użycie UNION połączyć zakotwiczony element z rekurencyjnym elementem rekurencyjnego CTE (myślę, że jest to możliwe w PostgreSQL), więc nie można wyeliminować duplikatów.

declare @i int

with cte as (
     select
         GroupID,
         row_number() over(order by Company) as rn
     from Table1
)
update cte set GroupID = rn

select @i = @@rowcount

-- while some rows updated
while @i > 0
begin
    update T1 set
        GroupID = T2.GroupID
    from Table1 as T1
        inner join (
            select T2.Company, min(T2.GroupID) as GroupID
            from Table1 as T2
            group by T2.Company
        ) as T2 on T2.Company = T1.Company
    where T1.GroupID > T2.GroupID

    select @i = @@rowcount

    update T1 set
        GroupID = T2.GroupID
    from Table1 as T1
        inner join (
            select T2.Publisher, min(T2.GroupID) as GroupID
            from Table1 as T2
            group by T2.Publisher
        ) as T2 on T2.Publisher = T1.Publisher
    where T1.GroupID > T2.GroupID

    -- will be > 0 if any rows updated
    select @i = @i + @@rowcount
end

;with cte as (
     select
         GroupID,
         dense_rank() over(order by GroupID) as rn
     from Table1
)
update cte set GroupID = rn

demonstracja skrzypiec sql

Próbowałem również algorytmu wyszukiwania wszerz. Pomyślałem, że może być szybszy (jest lepszy pod względem złożoności), więc podam tutaj rozwiązanie. Odkryłem, że nie jest to szybsze niż podejście SQL:

declare @Company nvarchar(2), @Publisher nvarchar(2), @GroupID int

declare @Queue table (
    Company nvarchar(2), Publisher nvarchar(2), ID int identity(1, 1),
    primary key(Company, Publisher)
)

select @GroupID = 0

while 1 = 1
begin
    select top 1 @Company = Company, @Publisher = Publisher
    from Table1
    where GroupID is null

    if @@rowcount = 0 break

    select @GroupID = @GroupID + 1

    insert into @Queue(Company, Publisher)
    select @Company, @Publisher

    while 1 = 1
    begin
        select top 1 @Company = Company, @Publisher = Publisher
        from @Queue
        order by ID asc

        if @@rowcount = 0 break

        update Table1 set
            GroupID = @GroupID
        where Company = @Company and Publisher = @Publisher

        delete from @Queue where Company = @Company and Publisher = @Publisher

        ;with cte as (
            select Company, Publisher from Table1 where Company = @Company and GroupID is null
            union all
            select Company, Publisher from Table1 where Publisher = @Publisher and GroupID is null
        )
        insert into @Queue(Company, Publisher)
        select distinct c.Company, c.Publisher
        from cte as c
        where not exists (select * from @Queue as q where q.Company = c.Company and q.Publisher = c.Publisher)
   end
end

demonstracja skrzypiec sql

Przetestowałem swoją wersję i Gordona Linoffa, aby sprawdzić, jak działa. Wygląda na to, że CTE jest znacznie gorszy, nie mogłem się doczekać, aż zakończy się w ponad 1000 rzędach.

Oto demonstracja skrzypiec SQL z losowymi danymi. Moje wyniki to:
128 wierszy :
moje rozwiązanie RBAR:190 ms
moje rozwiązanie SQL:27 ms
Rozwiązanie Gordona Linoffa:958ms
256 wierszy :
moje rozwiązanie RBAR:560 ms
moje rozwiązanie SQL:1226 ms
Rozwiązanie Gordona Linoffa:45371ms

To losowe dane, więc wyniki mogą nie być zbyt spójne. Myślę, że indeksy mogą zmienić czas, ale nie sądzę, że może to zmienić cały obraz.

stary wersja - używając tabeli tymczasowej, po prostu obliczając GroupID bez dotykania tabeli początkowej:

declare @i int

-- creating table to gather all possible GroupID for each row
create table #Temp
(
    Company varchar(1), Publisher varchar(1), GroupID varchar(1),
    primary key (Company, Publisher, GroupID)
)

-- initializing it with data
insert into #Temp (Company, Publisher, GroupID)
select Company, Publisher, Company
from Table1

select @i = @@rowcount

-- while some rows inserted into #Temp
while @i > 0
begin
    -- expand #Temp in both directions
    ;with cte as (
        select
            T2.Company, T1.Publisher,
            T1.GroupID as GroupID1, T2.GroupID as GroupID2
        from #Temp as T1
            inner join #Temp as T2 on T2.Company = T1.Company
        union
        select
            T1.Company, T2.Publisher,
            T1.GroupID as GroupID1, T2.GroupID as GroupID2
        from #Temp as T1
            inner join #Temp as T2 on T2.Publisher = T1.Publisher        
    ), cte2 as (
        select
            Company, Publisher,
            case when GroupID1 < GroupID2 then GroupID1 else GroupID2 end as GroupID
        from cte
    )
    insert into #Temp
    select Company, Publisher, GroupID
    from cte2
    -- don't insert duplicates
    except
    select Company, Publisher, GroupID
    from #Temp

    -- will be > 0 if any row inserted
    select @i = @@rowcount
end

select
    Company, Publisher,
    dense_rank() over(order by min(GroupID)) as GroupID
from #Temp
group by Company, Publisher

=> przykład skrzypiec sql