znajdź nazwy kolumn i nazwy tabel, do których odwołuje się SQL

Mam dla Ciebie świetne rozwiązanie, ale musisz zrobić dwie rzeczy:

1. Umieść SQL wewnątrz jednostki programu PL/SQL. A więc tak, do procedury składowanej, o której wspomniałeś.

2. Skompiluj tę jednostkę programu i wszystkie zależne tabele (czyli zainstaluj kod aplikacji) na instancji 12.2 (możesz pobrać 12.2 pod adresem http://www.oracle.com/technetwork/database/enterprise-edition/downloads/index.html lub możesz kupić Exadata Express Cloud Service na cloud.oracle.com lub otrzymać 300 USD kredytu na korzystanie z niej bezpłatnie przez miesiąc na cloud.oracle.com/tryit).

12.2 jest kluczowe, ponieważ funkcja, której NAPRAWDĘ chcesz użyć, nazywa się PL/Scope i jest to narzędzie kompilacyjne, które zbiera informacje o identyfikatorach PL/SQL (od 11.1) i użyciu SQL w PL/'SQL (od 12.2).

CREATE TABLE my_data (n NUMBER)
/

ALTER SESSION SET plscope_settings='identifiers:all, statements:all'
/

CREATE OR REPLACE PROCEDURE my_procedure (n_in IN NUMBER)
   AUTHID DEFINER
IS
   l_n           my_data.n%TYPE;

   CURSOR all_data_cur
   IS
          SELECT *
            FROM my_data
      FOR UPDATE OF n;
BEGIN
   INSERT INTO my_data (n)
        VALUES (n_in);

END;
/

  SELECT idt.line,
         idt.owner || '.' || idt.object_name code_unit, 
         idt.name column_name,
         RTRIM (src.text, CHR (10)) text
    FROM all_identifiers idt, all_source src
   WHERE     idt.usage = 'REFERENCE'
         AND idt.TYPE = 'COLUMN'
         AND idt.line = src.line
         AND idt.object_name = src.name
         AND idt.owner = src.owner
         AND idt.object_name = 'MY_PROCEDURE'
ORDER BY code_unit, line
/

LINE CODE_UNIT          COLUMN_NAME TEXT  
4   STEVEN.MY_PROCEDURE N           l_n           my_data.n%TYPE;
10  STEVEN.MY_PROCEDURE N           FOR UPDATE OF n;
12  STEVEN.MY_PROCEDURE N           INSERT INTO my_data (n)

Mam nadzieję, że to pomoże!

Dużo więcej przykładów PL/Scope na livesql.oracle.com. Po prostu wyszukaj "pl/scope" (duh).