Manipulowanie kolekcjami

Przynajmniej straciłeś definicję tabeli w drugim przypadku. To oświadczenie:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

deklaruje tylko typ obiektu (lub rekordu), a nie tabelę.

Musisz to zrobić w 2 krokach:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Następnie potrzebujesz kilku poprawek składni w skrypcie:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

AKTUALIZACJA

Powyższe rozwiązanie jest stosunkowo powolne ze względu na dużą liczbę przełączeń kontekstu. Ale porównania instancji obiektów złożonych nie można wykonać bezpośrednio w PL/SQL bez dodatkowej pracy.
Aby umożliwić Oracle rozpoznanie, czy instancje obiektów są takie same, czy różne, musimy zdefiniować metoda mapowania lub zamawiania typu obiektu . Oba rodzaje metod są niedozwolone, więc trzeba wybrać odpowiednią. Metody MAP działają szybciej i nie ma potrzeby zamawiania w naszym przypadku, więc zrób to:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Wdrożenie:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Następnie możliwe jest testowanie obiektów pod kątem równości w kodzie PL/SQL, takie jak prosty varchar2 w pierwszym przykładzie z pytania:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/